Hyper-V是微软的一款虚拟化软件，Hyper-V最大的好处就是Windows系统原生，支持性和稳定性都更好，并且安装和配置过程都十分简单，对于新手用户也很友好。但是Windows家庭版把Hyper-V的功能阉割掉了，可以看到Windows家庭版的Windows功能中没有Hyper-V的选项。

以下讲讲如何在Windows家庭版中开启Hyper-V的支持。本文以Windows10家庭中文版为例。

操作方法

1、打开文本文档，输入以下代码，并保存为hyper-v.cmd（注意：后缀名为cmd），文章最后也有写好的cmd文件供下载。

@echo off
title Windows家庭版解锁Hyper-V  By StarYu https://www.77bx.com
openfiles >nul 2>nul ||(
echo CreateObject^("Shell.Application"^).ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs" >nul 2>&1
goto:eof
)
del /f /q "%temp%\getadmin.vbs" >nul 2>nul
cls
echo ============================================================================
echo # Windows家庭版解锁Hyper-V
echo.
echo # By StarYu https://www.77bx.com
echo.
echo # 支持:
echo - Microsoft Windows 10 家庭版
echo - Microsoft Windows 11 家庭版
echo ============================================================================
echo # 按任意键开始解锁
echo.
pause >nul
echo.
for /f %%i in ('dir /b %SystemRoot%\servicing\Packages\*Hyper-V*.mum') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
Dism /online /enable-feature /featurename:Microsoft-Hyper-V-All /LimitAccess /ALL
cls
echo ============================================================================
echo #  破解完成，按任意键结束
echo ============================================================================
pause >nul

2、运行hyper-v.cmd，会弹出用户控制权限，点击 是 （这边是申请管理员权限运行），然后按任意键开始，大概等待几分钟

3、提示重启的时候，按 Y 键重启。重启后Hyper-V默认开启。

4、通过Windows 功能可以看到 Hyper-V的功能选项，并且已经开启

5、Windows管理工具，可以打开Hyper-V管理器。